Excel處理日常工作的時候，99%的人都會碰到一個操作的那就是數據查詢。說到數據查找都離不開一個函數，那就是vlookup函數，這個函數可以說的上是Excel函數中的NO.1。今天我們就來學習一下vlookup函數的七個經典查詢操作。

操作一：vlookup函數簡單查詢

案例說明：根據姓名趙宇查詢對應的工齡

函數公式：=VLOOKUP(G5,A:E,5,0)

函數說明：

vlookup函數作為查詢函數，它的參數主要有4個參數，默認查詢為向右查詢。如下說明：

1、第一參數G5代表的是需要查詢的值；第二參數A:E代表的是你需要查詢的數據區域；第三參數5，代表你要要查詢的數據在查詢值右邊的第幾列；第四參數0代表精確查找，1代表模糊查找。

操作二：vlookup函數數據向左查詢

案例說明：根據人員工號，向左查詢出對應的姓名

函數公式：

=VLOOKUP(G5,IF({1,0},B1:B7,A1:A7),2,0)

函數說明：

vlookup函數向左查詢的時候，需要搭配IF函數進行協同處理。

1、if函數在這裡的作用主要作為第二參數來使用。if函數的第一參數用{1，0}做一次數據判斷，從而形成新的二維數據區域。我們選中IF函數按F9可以解析如下圖：

2、如上IF函我們可以形成新的數據區域，當我們查詢到對應的第一參數工號之後，就可以通過向右查詢2位，找到對應的姓名。

操作三：vlookup+Column組合函數批量查詢數據

案例說明：利用column函數，根據姓名批量查詢出對應的工號、部門、性別、工齡等

函數公式：

=VLOOKUP($G5,$A$1:$E$7,COLUMN(B1),0)

函數說明：

1、我們這裡利用column函數來作為vlookup函數的第三參數，它的作用是返回當前值所在的列；

2、我們第三參數選擇B1單元格，返回的值為2。當我們向右拖動時會得到C1\D1\E1等，分別返回的值為3、4、5。這樣可以自動變化第三參數查詢數據。

操作四：vlookup函數對不連續單元格數據進行查詢

案例說明：我們需要在不影響之前填寫數據的情況下，利用vlookup函數對空白單元格中根據姓名找到對應的工號和部門。

函數公式：=VLOOKUP(B3,H2:J19,2,0)

函數說明：

1、查詢工號，首先選擇C3:C10區域按Ctrl+g，定位單元格選擇空格，這樣就選擇了全部空白單元格。

2、輸入上面的函數內容後，按Ctrl+Enter快捷鍵結束，這樣就可以空白單元格區域數據進行批量填充。查詢部門也是同理。

操作五：vlookup函數如何替換查找的錯誤值

案例說明：當我們原始數據中沒有對應的人時，查詢不到的時候結果會顯示為錯誤值#N/A。

函數公式：

=IFerror(VLOOKUP(E4,$B$2:$C$10,2,0),"")

函數說明：

1、當我們輸入vlookup函數查詢張強時，因為查不到人名所以會出現錯誤值；

2、IFerror函數為替換函數，當出現錯誤值時執行第二參數。

操作六：vlookup函數實現多條件查詢

案例說明：我們需要根據日期和單號查詢出對應的入庫數量和入庫型號。

函數公式：

{=VLOOKUP(G2&H2,IF({1,0},A:A&B:B,C:C),2,0)}

{=VLOOKUP(G2&H2,IF({1,0},A:A&B:B,D:D),2,0)}

函數說明：

1、vlookup函數進行多條件查詢的時候，需要用到&符號和IF函數搭配使用；

2、第一參數用&符號就是將日期和單號連接組成一個統一的條件值，if函數的作用在於重組一個新的數據查詢區域。

操作七：vlookup函數搭配通配符進行查詢

案例說明：通過通配符？查詢對應的王紅、王紅小兩位和三位名字的工號。

函數公式：

=VLOOKUP("王"&"?",$A$1:$B$7,2,0)

=VLOOKUP("王"&"??",$A$1:$B$7,2,0)

函數說明：

1、通配符？代表的是任意一個字符，王？代表的就是姓氏為王，名一個字總共兩個字的王姓工號。

現在你學會如何使用vlookup函數了嗎？